Trouver le nom d'une couleur

Mode d'emploi - Exemple

En Visual Basic, une couleur est codée par un nombre entier compris entre 0 et 16777215. Pour y voir plus clair, il faut exprimer cet entier en Hexadécimal.

L'hexadécimal corresponds à la base 16. Les "chiffres" de l'hexa sont : 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, A, B, C, D, E, F. Ainsi, le nombre hexadécimal "6B" corresponds au nombre décimal "107" (6*16 + 11).
En VB il est tout à fait possible de manipuler les nombres en hexa (c'est d'ailleurs recommandé pour les couleurs); il suffit juste de taper "&h" avant le nombre hexa. Par exemple, les deux instructions suivantes affectent la même valeur à la variable "x" :

x=107
x=&h6B

Au final, l'hexa est juste une convention d'AFFICHAGE, un nombre tapé sous la forme décimale sera stocké et traité par l'ordinateur DE LA MEME MANIERE qu'un nombre tapé sous la forme hexadécimale.

Revenons à nos couleurs ! Donc une couleur est un nombre qui va de 0 à 16777215 c'est à dire de &h000000 à &hFFFFFF. Et c'est là que l'usage de l'hexa est très interessant. Les deux premiers chiffres hexa correspondent à la quantité de bleu, les deux du milieu à la quantité de vert, et les deux derniers à la quantité de rouge.
On a donc couleur = &hBBVVRR, avec BB allant de &h00 à &hFF, avec VV allant de &h00 à &hFF, et avec RR allant de &h00 à &hFF
Par exemple, la couleur &h38FFC0 contient &h38 de bleu, &hFF de vert, &hC0 de rouge.

Alors que fait ma procédure ? Vous lui passez comme paramétre un nombre couleur (genre &h35AF0C), et elle vous retourne une chaîne contenant le nom de cette couleur !

Exemple d'utilisation :

Dim Couleur as Long
Dim a$
Couleur = &H38FFC0
a$ = NomCouleur$(Couleur)
MsgBox a$

On obtient le résultat suivant :

vert clair

Le code

Comme vous le remarquez, il n'y a pas une mais 4 fonctions. En fait, la fonction NomCouleur$ a besoin de 3 fonction annexes. Chacune de ces fonctions annexes a pour rôle d'extraire d'un nombre de couleur la quantité de bleu (ExtractB) de vert (ExtractG) ou de rouge (ExtractR).

Function ExtractB (ByVal Couleur)
    '** Extrait la composante Bleue d'une couleur
    Couleur = Couleur Mod 16777216
    ExtractB = (Couleur - ExtractR(Couleur) - ExtractG(Couleur) * 256) / 65536
End Function
Function ExtractG (ByVal Couleur)
    '** Extrait la composante Verte d'une couleur
    Couleur = Couleur Mod 16777216
    ExtractG = ((Couleur - ExtractR(Couleur)) / 256) Mod 256
End Function
Function ExtractR (ByVal Couleur)
    '** Extrait la composante Rouge d'une couleur
    Couleur = Couleur Mod 16777216
    ExtractR = (Couleur Mod 65536) Mod 256
End Function
Function NomCouleur$ (ByVal NCouleur&)
    '** Composantes des couleurs:
    Nb% = ExtractB(NCouleur&)
    Nr% = ExtractR(NCouleur&)
    Ng% = ExtractG(NCouleur&)
    '** moyenne des composantes (=luminosité):
    NMoy% = (Nb% + Nr% + Ng%) / 3
    '** ecart des composantes avec la moyenne:
    NEb% = Nb% - NMoy%
    NEr% = Nr% - NMoy%
    NEg% = Ng% - NMoy%
    If Abs(NEb%) < 7 And Abs(NEr%) < 7 And Abs(NEg%) < 7 Then
        '** On a identifié un gris:
        If NMoy% > 235 Then NomCouleur$ = "Blanc"
        If NMoy% <= 235 And NMoy% > 160 Then NomCouleur$ = "Gris clair"
        If NMoy% <= 160 And NMoy% > 100 Then NomCouleur$ = "Gris"
        If NMoy% <= 100 And NMoy% >= 20 Then NomCouleur$ = "Gris foncé"
        If NMoy% < 20 Then NomCouleur$ = "Noir"
    Else
        '** On a à faire à une couleur pas grise!
        '** Il y a donc une teinte dominantes:
        If Nb% >= Nr% And Nb% >= Ng% Then
            '** Le bleu est dominant:
            '** Le bleu domine t'il seul ?
            If Nb% > NMoy% * 2.1 Then
                If Nb% >= 150 Then NomCouleur$ = "Bleu"
                If Nb% < 150 Then NomCouleur$ = "Bleu foncé"
            Else
                If Abs(Nr% - Ng%) < 5 Then
                    '** Les deux autres couleurs sont equivalentes:
                    If (Nr% + Ng%) / 2 < 20 Then
                        '** elles sont faibles:
                        If Nb% >= 150 Then NomCouleur$ = "Bleu"
                        If Nb% < 150 Then NomCouleur$ = "Bleu foncé"
                    Else
                        '** elles sont influentes:
                        If Nb% >= 150 Then NomCouleur$ = "Bleu clair"
                        If Nb% < 150 Then NomCouleur$ = "Bleu"
                    End If
                Else
                    '** Il faut prendre en compte l'autre couleur
                    If Nr% > Ng% Then
                        '** L'autre couleur est le rouge
                        If Nb% >= 160 Then NomCouleur$ = "Violet-bleu clair"
                        If Nb% < 160 And Nb% >= 100 Then NomCouleur$ = "Violet-bleu"
                        If Nb% < 100 Then NomCouleur$ = "Violet-bleu foncé"
                    Else
                        '** L'autre couleur est le vert
                        If Nb% >= 140 Then NomCouleur$ = "Bleu ciel"
                        If Nb% < 140 And Nb% >= 90 Then NomCouleur$ = "Bleu"
                        If Nb% < 90 Then NomCouleur$ = "Bleu foncé"
                    End If
                End If
            End If
        End If
        '
        If Nr% >= Nb% And Nr% >= Ng% Then
            '** Le rouge est dominant:
            '** Le rouge domine t'il seul ?
            If Nr% > NMoy% * 2.3 Then
                If Nr% >= 150 Then NomCouleur$ = "Rouge"
                If Nr% < 150 Then NomCouleur$ = "Rouge foncé"
            Else
                If Abs(Nb% - Ng%) < 5 Then
                    '** Les deux autres couleurs sont equivalentes:
                    If (Nb% + Ng%) / 2 < 20 Then
                        '** elles sont faibles:
                        If Nr% >= 150 Then NomCouleur$ = "Rouge"
                        If Nr% < 150 Then NomCouleur$ = "Rouge foncé"
                    Else
                        '** elles sont influentes:
                        If Nr% >= 150 Then NomCouleur$ = "Rose"
                        If Nr% < 150 Then NomCouleur$ = "Rouge"
                    End If
                Else
                    '** Il faut prendre en compte l'autre couleur
                    If Nb% > Ng% Then
                        '** L'autre couleur est le bleu
                        If Nr% >= 160 Then NomCouleur$ = "Violet clair"
                        If Nr% < 160 And Nr% >= 100 Then NomCouleur$ = "Violet"
                        If Nr% < 100 Then NomCouleur$ = "Violet foncé"
                    Else
                        '** L'autre couleur est le vert
                        If Ng% * 1.5 < Nr% Then
                            If Ng% >= 170 Then NomCouleur$ = "Jaune"
                            If Ng% < 170 And Ng% >= 120 Then NomCouleur$ = "Orange"
                            If Ng% < 120 Then NomCouleur$ = "Marron"
                        Else
                            If Ng% >= 170 Then NomCouleur$ = "Jaune"
                            If Ng% < 170 And Ng% >= 140 Then NomCouleur$ = "Marron"
                            If Ng% < 140 Then NomCouleur$ = "Kaki"
                        End If
                    End If
                End If
            End If
        End If
        '
        If Ng% > Nr% And Ng% >= Nb% Then
            '** Le vert est dominant:
            '** Le vert domine t'il seul ?
            If Ng% > NMoy% * 2.1 Then
                If Ng% >= 190 Then NomCouleur$ = "Vert clair"
                If Ng% < 190 And Ng% >= 120 Then NomCouleur$ = "Vert"
                If Ng% < 120 Then NomCouleur$ = "Vert foncé"
            Else
                If Abs(Nr% - Nb%) < 5 Then
                    '** Les deux autres couleurs sont equivalentes:
                    If (Nr% + Nb%) / 2 < 20 Then
                        '** elles sont faibles:
                        If Ng% >= 190 Then NomCouleur$ = "Vert clair"
                        If Ng% < 190 And Ng% >= 120 Then NomCouleur$ = "Vert"
                        If Ng% < 120 Then NomCouleur$ = "Vert foncé"
                    Else
                        '** elles sont influentes:
                        If Ng% >= 150 Then NomCouleur$ = "Vert clair"
                        If Ng% < 150 Then NomCouleur$ = "Vert"
                    End If
                Else
                    '** Il faut prendre en compte l'autre couleur
                    If Nr% > Nb% Then
                        '** L'autre couleur est le rouge
                        If Ng% >= 160 Then NomCouleur$ = "Vert clair"
                        If Ng% < 160 And Ng% >= 100 Then NomCouleur$ = "Vert kaki"
                        If Ng% < 100 Then NomCouleur$ = "Vert kaki foncé"
                    Else
                        '** L'autre couleur est le bleu
                        If Ng% >= 180 Then NomCouleur$ = "Bleu-vert clair"
                        If Ng% < 180 And Ng% >= 120 Then NomCouleur$ = "Bleu-vert"
                        If Ng% < 120 Then NomCouleur$ = "Bleu-vert foncé"
                    End If
                End If
            End If
        End If
        '
    End If
End Function

Explications

Rien de compliqué ici !
On extrait d'abord la quantité de chaque couleur élémentaire (Bleu, Vert, Rouge), puis on effectue une serie de tests de comparaisons pour trouver un nom de couleur adéquat.